TEMPLATE = app
TARGET = Tester
QT += core gui opengl
CONFIG += debug_and_release \
    build_all

mac {
	CONFIG += x86_64
}

#Path defines
SDK_PATH = $${PWD}/..
TESTER_PATH = $${PWD}/Tester/
RENDER_PATH = $${PWD}/Tester/videorender
PLAYSND_PATH = $${PWD}/Tester/PlaySnd


DEFINES     += QT_LARGEFILE_SUPPORT
DEFINES     += SDK_STATIC
DEPENDPATH  += $${TESTER_PATH}/
MOC_DIR     += $${TESTER_PATH}/GeneratedFiles/debug
UI_DIR      += $${TESTER_PATH}/GeneratedFiles
RCC_DIR     += $${TESTER_PATH}/GeneratedFiles

#included path
INCLUDEPATH += $${TESTER_PATH}/GeneratedFiles \
               $${TESTER_PATH}/GeneratedFiles/Debug \
               $${TESTER_PATH}/GeneratedFiles/Release \
               $${TESTER_PATH}/ \
               $${SDK_PATH}/include \
               $${RENDER_PATH}/ \
               $${PLAYSND_PATH}/


#included pri
include(./Tester/Tester.pri)

mac {
	SOURCES -= $${RENDER_PATH}/glprocs.c
}

CONFIG(debug, debug|release) {
    OBJECTS_DIR=.obj.debug
    LIBS += -L$${SDK_PATH}/lib -lNpClient_d
    DESTDIR = debug
} else {
    OBJECTS_DIR=.obj.release
    LIBS += -L$${SDK_PATH}/lib -lNpClient
    DESTDIR = release
}
